国内のウェブログサービスのシェアを(超適当に)グラフ化

何かを比較するときに、Google での検索件数で比べてみるということはよくやります。Google Web APIs を使えば、プログラムから Google にクエリを投げて、その検索結果の件数を取得することができるので、これを使って国内のウェブログサービスのシェアを(かなり適当に)グラフ化してみました。

「かなり適当に」というのはなぜかというと、検索キーワードの選定が適当だからです。それぞれ以下のキーワードで検索しました。

・ココログ: 'Powered by ココログ'
・TypePad: 'Powered by TypePad'
・Blogger: 'This page is powered by Blogger'
・livedoor Blog: 'site:blog.livedoor.jp syndicate this site'
・Doblog: 'site:www.doblog.com "[ RSS ]"'
・NewsHandler: 'site:blog.nettribe.org Powered by News Handler'

こんな具合で各サービスのツールが出力するウェブログに特徴的なクエリを作って、それの Google 検索件数を調べたわけですが、クエリの構成がフェアじゃないので、細かいところでデータに信憑性は全くありません。でもまあ、相対的に考えれば誤差の範囲かもしれないですが。(お遊びで作ったものなので、あのサービスが入ってないじゃないか！とかいうツッコミは簡便してください。)

データは、上記のクエリを"日本語検索"にかけた結果になります。結果はこんな具合です。

Google API によるウェブログシェアグラフ: クリックで拡大

スクリプトを一日一回走らせてみることにしました。夜中の3時に回ります。何ヵ月後かにこのエントリを再度見てみてください。シェアがどう変化しているか、見物です。=)

超適当なのでデータに信憑性はないのですが、予想以上にあちこちのサイトから参照されてしまいました。ココログの HTML タグの構成が変わったことなどもあって、いまのグラフは以前以上にまったくあてになりません。ご注意ください。クエリを再構成したものを近々アップします。

スクリプトの中身はこんな感じです。SOAP::Lite で Google API にアクセスし、その結果を GD::Graph::pie で描写という割とお粗末なものです。

#!/usr/local/bin/perl
 
use strict;
use warnings;
use SOAP::Lite;
use utf8;
use GD::Graph::pie;
use FileHandle;
use constant GOOGLE_KEY => '*********';
use constant GOOGLE_WSDL => './GoogleSearch.wsdl';
 
my $dir = "/home/naoya/public_html/wc";
my %query = (
     'Cocolog'       => 'Powered by ココログ',
     'TypePad'       => 'Powered by TypePad',
     'Blogger'       => 'This page is powered by Blogger',
     'livedoor Blog' => 'site:blog.livedoor.jp syndicate this site',
     'Doblog'        => 'site:www.doblog.com "[ RSS ]"',
     'NewsHandler'   => 'site:blog.nettribe.org Powered by News Handler',
);
 
eval {
    my $google_search = SOAP::Lite->service("file:" . GOOGLE_WSDL);
    my (@label, @count);
    for (keys %query) {
	my $result = $google_search->doGoogleSearch(
		    GOOGLE_KEY, # key
		    $query{$_}, # query
		    0,          # start
		    1,          # maxResults
		    'true',     # filter
		    '',         # restrict
		    'false',    # safeSearch
		    'lang_ja',  # lr
		    'utf8',     # ie
		    'utf8',     # oe
		    );
	push @count, $result->{estimatedTotalResultsCount};
	push @label, $_;
    }
    my @data = (\@label, \@count);
 
    output_graph("$dir/wc.png", make_gd(\@data, 400, 300, { title => scalar localtime(time) }));
    output_graph("$dir/wc_thumb.png", make_gd(\@data, 120, 90));
}; if (my $errstr = $@) {
    die $errstr;
}
  
sub make_gd {
    my ($data, $width, $height, $opt) = @_;
    my $graph = GD::Graph::pie->new($width, $height);
    $graph->set( %$opt );
    return $graph->plot($data);
}
 
sub output_graph {
    my ($path, $gd) = @_;
    my $fh = FileHandle->new("> $path") or die "cannot open image file.: $!";
    binmode $fh;
    $fh->print( $gd->png );
    $fh->close;
}
 
exit(0);
 
__END__

Posted by naoya at December 23, 2003 03:12 AM | トラックバック (29)